MacWorld 2000 June (IDG)/Macworld_June_2000.iso/Shareware World/Utilities/Printing/MacGhostView/ps2pdf script

Text File | 2000-03-30 | 1.6 KB | 45 lines | [TEXT/ToyS]

-- Save this script as an application and then drop a postscript file on it.
-- Use -dCompatibilityLevel=1.2 to convert PostScript to PDF 1.2 (Acrobat 3-and-later compatible).
-- Use -dCompatibilityLevel=1.3 to convert PostScript to PDF 1.2 (Acrobat 4-and-later compatible).



on open (theList)
    repeat with afile in theList
        convert(afile)
    end repeat
    quit
end open

on convert(afile)
    set old_delimits to AppleScript's text item delimiters
    set AppleScript's text item delimiters to ":"
    -- pull the path out as a string and strip off the filename
    set path_text to (afile as text)
    set path_list to (text items of path_text)
    set final_path to items 1 thru ((count of path_list) - 1) of path_list
    set infile to last item of path_list
    set working_directory to (final_path as string) & ":"
    set AppleScript's text item delimiters to "."
    set file_text to (text items of infile)
    set basename to item 1 of file_text
    set AppleScript's text item delimiters to old_delimits
    if infile = "" then
        display dialog "No Postscript file selected." buttons {"OK"} default button 1
        return
    end if
    set outfile to basename & ".pdf"
    set command to "gs -dCompatibilityLevel=1.2 -dMaxSubsetPct=100 -dNOPAUSE -dBATCH -sDEVICE=pdfwrite -sOutputFile=" & outfile & space  & "-c save pop -f" & space & infile
    with timeout of 300 seconds
        tell application "ps2pdf"
            activate
            set status to (exec command in the folder alias working_directory)
            if status = 0 then
                tell application "Finder"
                    set creator type of file (working_directory & outfile) to "CARO"
                    set file type of file (working_directory & outfile) to "PDF "
                end tell
            end if
        end tell
    end timeout
end convert